grub-theme-package/PKGBUILD

# Maintainer: davedatum <trom@davedatum.com>

pkgbase=grub-theme-live-tromjaro
pkgname=('grub-theme-live-common' 'grub-theme-live-tromjaro' 'grub-theme-tromjaro')
pkgver=18.1
pkgrel=1.2

pkgdesc='TROMjaro Linux grub theme'
arch=('any')
url="https://git.trom.tf/TROMjaro/grub-theme-settings"
license=('GPL')
makedepends=('git')
source=("grub-theme-settings::git+$url.git#commit=56320c88cb4f592d273d7f1e989ccf163c3129b6")
sha256sums=('SKIP')

package_grub-theme-live-common() {
    depends=('grub')
    conflicts=('grub-theme-live-dev')

    cd grub-theme-settings
    make PREFIX=/usr DESTDIR=${pkgdir} install_common
}
package_grub-theme-live-tromjaro() {
    depends=('grub-theme-live-common')
	conflicts=('grub-theme-live-common-dev' 'grub-theme-live-manjaro')
	
    cd grub-theme-settings
    make PREFIX=/usr DESTDIR=${pkgdir} install_manjaro
}

package_grub-theme-tromjaro() {
	depends=('grub')
	conflicts=('grub-theme-tromjaro-dev' 'grub-theme-manjaro' 'grub-theme-manjaro-dev')
	install=manjaro-theme.install
    
    cd grub-theme-settings/manjaro-live
    sed -i -e 's,.*text = "Welcome to TROMjaro".*,#text = "Welcome to TROMjaro",' theme.txt #remove welcome message
    find . -type f -exec install -D -m644 {} ${pkgdir}/usr/share/grub/themes/manjaro/{} \;
}