grub-theme-package/PKGBUILD

# Maintainer: davedatum <trom@davedatum.com>

pkgbase=grub-theme-live-tromjaro
pkgname=('grub-theme-live-common' 'grub-theme-live-tromjaro' 'grub-theme-tromjaro')
pkgver=18.0
pkgrel=1.1

pkgdesc='TROMjaro Linux grub theme'
arch=('any')
url="https://gitlab.com/tromsite/tromjaro/grub-theme"
license=('GPL')
makedepends=('git')
source=("grub-theme::git+$url.git#commit=354496ecee545f666222c17c603c70ba1f45f873")
sha256sums=('SKIP')

package_grub-theme-live-common() {
    depends=('grub')
    conflicts=('grub-theme-live-dev')

    cd grub-theme
    make PREFIX=/usr DESTDIR=${pkgdir} install_common
}
package_grub-theme-live-tromjaro() {
    depends=('grub-theme-live-common')
	conflicts=('grub-theme-live-common-dev' 'grub-theme-live-manjaro')
	
    cd grub-theme
    make PREFIX=/usr DESTDIR=${pkgdir} install_tromjaro
}

package_grub-theme-tromjaro() {
	depends=('grub')
	conflicts=('grub-theme-tromjaro-dev' 'grub-theme-manjaro' 'grub-theme-manjaro-dev')
	install=tromjaro-theme.install
    
    cd grub-theme/tromjaro-live
    sed -i -e 's,.*text = "Welcome to TROMjaro".*,#text = "Welcome to TROMjaro",' theme.txt #remove welcome message
    find . -type f -exec install -D -m644 {} ${pkgdir}/usr/share/grub/themes/tromjaro/{} \;
}