# Maintainer: TROM <contact@tromsite.com>
pkgname=tromjaro-theme-switcher
pkgver=2.2
pkgrel=2
pkgdesc="TROMjaro Theme switcher application"
arch=('x86_64')
url="https://git.trom.tf/TROMjaro/theme-switcher-package"
license=(unknown)
depends=('tromjaro-fixes'
         'xfconf'
         'gtk4'
         'colloid-gtk-theme-git'
         'colloid-dracula-gtk-theme-git'
         'colloid-gruvbox-gtk-theme-git'
         'colloid-nord-gtk-theme-git'
         'colloid-everforest-gtk-theme-git'
         'colloid-catppuccin-gtk-theme-git'
         'zafiro-icon-theme')
makedepends=('choosenim')
provides=('tromjaro-theme-switcher')
backup=()
options=(!strip)
source=("themeSwitcher.nim"
        "tromjaro-theme-switcher.desktop"
        "tromjaro-theme-switcher.svg"
        "icons.tar.gz::https://www.drive.tromsite.com/s/ysM33nJAkpro85b/download/icons.tar.gz")
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP')
prepare() {
	# Disable telemetry in choosenim if user is running it for the first time
	[ -f "$HOME"/.choosenim/analytics ] || {
		mkdir -p "$HOME"/.choosenim
		touch "$HOME"/.choosenim/analytics
	}
	echo 'Install Nim if not already installed:'
	choosenim stable
	echo 'Update Nim to the latest stable release:'
	choosenim update stable
	echo 'Refresh nimble package list:'
	"$HOME"/.nimble/bin/nimble --nim:"$HOME"/.nimble/bin/nim refresh
	echo 'Install owlkettle from the latest git commit:'
	"$HOME"/.nimble/bin/nimble --nim:"$HOME"/.nimble/bin/nim install owlkettle
}
build(){
	echo 'Compile themeSwitcher.nim for release build:'
	"$HOME"/.nimble/bin/nim c -d:release --out:${srcdir}/themeSwitcher ${srcdir}/themeSwitcher.nim
}
package() {
	# copy icons
	install -d ${pkgdir}/usr/share/tromjaro-theme-switcher/icons/Styles
	install -Dm644 ${srcdir}/icons/Styles/*    ${pkgdir}/usr/share/tromjaro-theme-switcher/icons/Styles

	for source_dir in "${srcdir}/icons/Accent Colors"/*; do
		dest_dir="${pkgdir}/usr/share/tromjaro-theme-switcher/icons/Accent Colors/${source_dir##*/}"
		install -d "$dest_dir"
		install -Dm644 "$source_dir"/*    "$dest_dir"
	done

	# copy executables
	install -Dm644  ${srcdir}/tromjaro-theme-switcher.desktop    ${pkgdir}/usr/share/applications/tromjaro-theme-switcher.desktop
	install -Dm755  ${srcdir}/themeSwitcher    ${pkgdir}/usr/bin/tromjaro-theme-switcher

	# copy the icon
	install -d ${pkgdir}/usr/share/icons/hicolor/scalable/apps
	install -Dm644 ${srcdir}/tromjaro-theme-switcher.svg    ${pkgdir}/usr/share/icons/hicolor/scalable/apps
}