gconf-package/PKGBUILD

# Maintainer: davedatum <ask at davedatum dot come>

pkgbase=tromjaro-settings
pkgname=("tromjaro-settings" "tromjaro-branding" "tromjaro-gnome-shell-fix")
pkgver=1.3
pkgrel=1
arch=("any")
url="https://gitlab.com/tromsite/tromjaro/gnome-settings"
license=("GPL")
source=("tromjaro-settings::git+$url.git"
		"tromjaro-logo.png"
		"tromjaro-branding-install.hook"
		"tromjaro-branding-remove.hook")
makedepends=("git")
sha256sums=('SKIP'
            '9c870f664d3e479ddc5ac3752ad92df95f9b07a46382ec2d0b8d20712ee67060'
            '85ef166fc107808ada7449d23eef9a95861e4311527a741becf27cfbd2f4399a'
            'd17518ef6b9635c78fa333487f148570c65005adee684f173c6961dbfab09cd5')

_inst_dir(){
	install -d "${pkgdir}/etc"
	cp -r "${srcdir}/${pkgbase}/skel" "${pkgdir}/etc/"

	chmod -R 755 "${pkgdir}/etc/skel"

}

package_tromjaro-settings() {

pkgname=tromjaro-settings
pkgdesc="TROMjaro Settings"
depends=('gnome-shell')

	_inst_dir	

	install -Dm644 "${srcdir}/${pkgbase}/schemas/99_tromjaro-settings.gschema.override" \
					"${pkgdir}/usr/share/glib-2.0/schemas/99_tromjaro-settings.gschema.override"

	install -Dm644 "${srcdir}/${pkgbase}/schemas/user" "${pkgdir}/etc/dconf/profile/user"
	install -Dm644 "${srcdir}/${pkgbase}/schemas/10_tromjaro-defaults" "${pkgdir}/etc/dconf/db/site.d/10_tromjaro-defaults"
	install -Dm644 "${srcdir}/${pkgbase}/schemas/mimeapps.list" "${pkgdir}/usr/share/applications/mimeapps.list"
	 
}

package_tromjaro-branding() {

pkgname=tromjaro-branding
pkgdesc="TROMjaro Branding"
depends=('gnome-shell' 'dconf')

	install -Dm644 "${srcdir}/${pkgbase}/schemas/gdm" "${pkgdir}/etc/dconf/profile/gdm"
	install -Dm644 "${srcdir}/${pkgbase}/schemas/10_tromjaro-branding" "${pkgdir}/etc/dconf/db/gdm.d/10_tromjaro-branding"

	install -Dm644 "${srcdir}/tromjaro-logo.png" "${pkgdir}/usr/share/icons/manjaro/maia/tromjaro-logo.png"
	install -Dm644 "${srcdir}/tromjaro-branding-install.hook" "${pkgdir}/usr/share/libalpm/hooks/tromjaro-branding-install.hook"
	install -Dm644 "${srcdir}/tromjaro-branding-remove.hook" "${pkgdir}/usr/share/libalpm/hooks/tromjaro-branding-remove.hook"
	
}


package_tromjaro-gnome-shell-fix() {
pkgname=tromjaro-gnome-shell-fix
pkgdesc="fix for gnome extensions disabled on logout"
depends=("gnome-shell")

	install -Dm644 "${srcdir}/${pkgbase}/patches/tromjaro-gnome-shell-fix/tromjaro-gnome-shell-fix.install" \
					"${pkgdir}/usr/bin/tromjaro-gnome-shell-fix.install"

	install -Dm644 "${srcdir}/${pkgbase}/patches/tromjaro-gnome-shell-fix/tromjaro-gnome-shell-fix.sh" \
					"${pkgdir}/usr/bin/tromjaro-gnome-shell-fix"

	install -Dm644 "${srcdir}/${pkgbase}/patches/tromjaro-gnome-shell-fix/tromjaro-gnome-shell-fix.desktop" \
					"${pkgdir}/etc/xdg/autostart/tromjaro-gnome-shell-fix.desktop"

}